%% Zdrojovy kod znaku ASHK ve formatu MetaPost
%% dle navrhu Jiriho Sury zpracoval:
%% Miroslav Broz (miroslav.broz@email.cz), 30. 1. 2002

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

input mbmac;

prologues:=1;

path p[];
color bg[];
picture v[];

w:=.75mm;	% tloustka car
bg3=white;	% zakladni pozadi

%% definice obzoru Hradce

d11=5.5;
d12=8.25;
d13=3.5;
p11=(0,0)--(0,6)--(-.75,7)--(-.75,9)--(-.25,10)--(.5,9)--(2,16);
p12=(0,0)--(0,9)--(.25,9)--(.25,13.5)--(.75,13.5)--(.75,16)--(2,16)--(2,16.5)
  {dir150}..{up}(.5,18.5)..{dir70}(2.5,21.5)..(3.25,22.5)--(3.25,24)--(3.9,25.5)--(4,27);
p13=(0,0)--(0,4.25)--(1,4.25)--(1,4.75){dir165}..{up}(.25,5.75)..{dir45}(1.4,7)--(1.4,7.75)--(.5d13,8.5);
for i=11,12,13:
  p[i]:=p[i]--reverse p[i] reflectedabout ((.5d[i],0),(.5d[i],1));
endfor;

p1=(0,-8)--(0,0)--(8.5,0)--(11,-4)--(16,-4)--p11 shifted (16,1)--p11 shifted (25,1)
  --(35.5,1)--(38,-6)--(41,-6)--(41,0)--p12 shifted (41.5,0)--p13 shifted (57,0)
  --p13 shifted (69,0)--(83.5,0)--(83.5,-8)--cycle;

tmp:=-15;
d14=xpart point length p1-1 of p1;
p14=(0,tmp)--p1--(d14,tmp)--cycle;

for i=1,14: p[i]:=p[i] scaled u; endfor;
d14:=d14*u;

%% Saturn s prstencem

prstenec=0;
2r1=55u;
p2=fullcircle scaled 2r1;

p3=(36.5,0){up}..tension 1.3..(31,5.5)..(14.5,10)..{left}(0,10.5);
p4=(63,0){up}..(61.5,4)..(54.5,10)..(34,18)..{left}(0,23);
for i=3,4:
  l[i]=length p[i];
  p[i]:=p[i] scaled u;
  p[i]:=p[i] & reverse p[i] xscaled -1;
  p[i]:=p[i] & reverse p[i] yscaled -1--cycle;
endfor;

p5=subpath(10.75,length p3) of p3;

(n1,n2)=subpath (2l3,3l3) of p3 intersectiontimes p2;
(n3,n4)=subpath (2l4,3l4) of p4 intersectiontimes p2;
p6=subpath(8-(n2-4)+0.03,8+n2) of p2;
n4:=n4+0.1;

%% projekce siluety Hradce Kralove

def tr(expr a,b)=
  hide(
    zz:=b/(b++r)*r;
    xx:=(r+-+zz)/(a++r)*a;
    yy:=(r+-+zz)/(a++r)*r;
  )
  a_p(xx,yy,zz)
enddef;

%a_set(0,20);
a_set(0,20);
%r=0.75;
r=0.5;
maxi:=10;
p15:=p1 scaled (1/d14) shifted (-.5,0);
for j=15:
  p[j]:=tr(xpart point 0 of p[j], ypart point 0 of p[j])
    for i=1 upto maxi*(length p[j]): --tr(xpart point i/maxi of p[j], ypart point i/maxi of p[j])  endfor;
%  p[j]:=p[j] scaled (2r1) shifted (0,12u);
  p[j]:=p[j] scaled (2.25r1) shifted (0,9u);
endfor;

p16:=p15--cycle;
p15:=subpath(maxi,length p15-2maxi) of p15;

%% pismena ASHK

%A
z1=(-21u,-9.25u);
z2=(-34u,-18.5u);
z3=(-29.5u,-19.5u);
z4=(-25.5u,-16.75u);
z5=(-21u,-17.5u);
z6=(-21u,-21u);
z7=(-17u,-21.5u);
z8=(-17u,-10u);
z9=(-22.66u,-14.33u);
z10=(-20.66u,-14.66u);
z11=(-20.66u,-13u);

p20=z9--z10--z11--cycle;
p21=z1--z2--z3--z4--z5--z6--z7--z8--cycle;

%S
clearxy;
z1=(-14u,-18u);
z2=(-13.33u,-21u);
z3=(-10u,-22.33u);
z4=(-5.5u,-22.5u);
z5=(-2.75u,-21.5u);
z6=(-2u,-19.5u);
z7=(-3.75u,-17.25u);
z8=(-6.25u,-16.25u);
z9=(-8.5u,-14.5u);
z10=(-7u,-13.5u);
z11=(-5u,-14.5u);
z12=(-1.75u,-14.5u);
z13=(-2.25u,-12u);
z14=(-5.5u,-11u);
z15=(-8.5u,-11u);
z16=(-11.5u,-12u);
z17=(-12.5u,-14u);
z18=(-11.5u,-15.66u);
z19=(-8.75u,-17.5u);
z20=(-6.5u,-18.66u);
z21=(-5.75u,-19.5u);
z22=(-8u,-20.5u);
z23=(-10.25u,-20u);
z24=(-11.25u,-18.33u);

p22=z1..z2..z3---z4..tension 1.2..z5..tension 1.2..z6{up}..z7..z8
  ..tension 1.2..z9..tension 1.2..z10..z11--z12..z13
  ..tension 1.2..z14..z15..tension 1.2..z16..tension 1.2..z17..z18
  ..z19..z20..tension 1.2..z21..tension 1.2..z22..z23..z24--cycle;

%H
clearxy;
z1=(1.5u,-11.5u);
z2=(1.5u,-23u);
z3=(5.125u,-23u);
z4=(5u,-18.66u);
z5=(9.25u,-18.5u);
z6=(10u,-22.66u);
z7=(13.5u,-22.33u);
z8=(11.33u,-11.33u);
z9=(8.33u,-11.5u);
z10=(8.66u,-15.5u);
z11=(5u,-15.66u);
z12=(4.75u,-11.5u);

p23=z1--z2--z3--z4--z5--z6--z7--z8--z9--z10--z11--z12--cycle;

%K
clearxy;
z1=(14.5u,-11u);
z2=(17.5u,-21.66u);
z3=(21.75u,-21u);
z4=(20.5u,-17.33u);
z5=(27u,-20u);
z6=(32.75u,-19u);
z7=(21.5u,-15u);
z8=(25.5u,-8.25u);
z9=(21.25u,-9.5u);
z10=(18.75u,-14.25u);
z11=(17.33u,-10.66u);

p24=z1--z2--z3--z4--z5--z6--z7--z8--z9--z10--z11--cycle;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

def znak=

if (prstenec=0): bg4:=bg3; fi;
penc 1w;
fill subpath (0, 2l3) of p3--reverse subpath (0, 2l4) of p4--cycle withcolor bg4;
draw subpath (0, 2l3) of p3;
draw subpath (0, 2l4) of p4;
fill p2 withcolor bg3;
fill subpath (2l3, length p3) of p3--reverse subpath (2l4, length p4) of p4--cycle withcolor bg4;
draw subpath(2l3,7.5) of p3;
draw p5;
draw subpath(2l4,10.9) of p4;
draw subpath(13,length p4) of p4;
draw p6;
draw point 0 of p5--point 0 of p6;
draw subpath(n4,8-(n4-4)-0) of p2;

penc .7w;
draw p15;

penc .8w;
draw p20;
penc 1w;
for i=21,22,23,24: draw p[i]; endfor;

enddef;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

beginfig(1);

%% radialni barevny podklad

bg1:=(42,63,109)/255*1.5;
bg2:=white;

maxi:=100;
dr:=160u/maxi;
bgr:=0.4;

p0:=unitsquare shifted (-.5,-.5) scaled 150u yscaled .5;
fill p0 withcolor bg2;

for i=0 upto maxi-1:
  fill fullcircle scaled ((maxi-i)*dr) yscaled bgr withcolor ((i/maxi)[bg2,bg1]);
endfor;

v0:=currentpicture;

znak;

endfig;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

end.